MS-SQL 의 datetime 포맷을 변형하는 함수입니다.
function view_date(target_date)
Dim yy,mm,dd,h,mi,result
yy= year(target_date)
mm = right("0" & month(target_date),2)
dd = right("0" & day(target_date),2)
h = right("0" & hour(target_date),2)
mi = right("0" & minute(target_date),2)
result = yy & "-" & mm & "-" & dd & " " & h & ":" & mi & ""
view_date = result
end function
view_date 함수는 datetime 포맷을 2007-12-25 11:22:32 와 같이 변형하여 주십니다.
출력양식을 변경 하시고자 한다면 result변수에 값 할당부분을 수정하여 주시면 됩니다.
저자: 4GuysFromRolla | 날짜: 2005년 01월 24일
PHP에는 phpinfo()란 유용한 함수가 있는 반면 ASP에는 이런 용도의 함수가 존재하질 않는다. 하지만 ASP의 내장 함수를 이용하면 이와 비슷한 결과를 얻을 수 있는 사용자 정의 함수를 만들 수가 있다. 다음은 phpinfo() 함수에 해당하는 aspinfo() 함수 내용이다. 아래 소스를 asp로 만들어 웹서버 상에서 테스트 해보기 바란다.
|
<% |
페이징처리를 이해하자
<%
출처: http://cafe.naver.com/webdeveloper.cafe
'페이징 처리는 게시판이나 목록부분을 사용자에게 제공할때 꼭 들어가는 부분입니다.
'하지만 개발자에게 있어서는 잠시 숙고의 시간을 갖게하는 조금 까다로운 부분이기도 합니다.
'그래서 그런지 웹사이트에서 페이징을 치기만 하면 페이징에 대해서 많은시간 숙고하신 머리좋은 분들이
'개발해논 페이징 함수들이 많이 있습니다. 갖다 쓰면 그만입니다. 그래도 한번쯤은 이해하고 갖다쓰면
'좋을것 같기에 아주 간단한 예제하나 올립니다. 기존에 웹상에 존재하는 것들보다는 더욱 간단하게 작성
'해서(?) 성능 이런거는 생각안합니다. 보시면 바로 이해되게 쉽게 작성할려구 노력했습니다.
참고로 닷넷에서는 GridView를 쓰시면 페이징이 옵션선택에 따라서 바로 달립니다.
%>
<style type="text/css">
<!--
a:visited {color:#000000; text-decoration:none }
-->
</style>
<%
dim listfile, tblname, pagesize, pageset
listfile = "pagesample.asp" '페이지가 선택되었을때 리스트를 뿌려줄 화일명입니다. 여기서는 바로 이페이지입니다.
tblname = "TEST_TBL" '테이블명입니다.
pagesize = 10 '한 페이지에 뿌려질 글의 갯수입니다.
pageset = 10 '페이지 이동을 위해서 하단에 뿌려줄 페이지의 갯수를 지정합니다.
'현재 페이지를 request.querystring으로 받아옵니다. 너무나 쉬운 구문이므로 넘어갑니다.
'참고로 request개체에서 컬렉션 생략시 우선순위는 다음과 같습니다
' QuertyString > Form > Cookies > ClientCertificate > ServerVariables <-- !!요놈들이 컬렉션(collection)
if request("page") = "" then
page = 1
else
page = request("page")
end if
'db연결부분입니다. 개발자의 취향에 따라서 좀 달라지는 부분입니다.
'지금 보안을 위해서 연결부분을 테스트로 적었으니 자신의 odbc설정에 맞게 직접 구성해 주셔야 합니다.
function dbconnection
dim dbCon, strConnect
strConnect="dsn=test;uid=test;pwd=password;"
set dbCon = server.Createobject("adodb.connection")
dbCon.open strConnect
set dbConnection = dbCon
end function
set conn = dbConnection
set rs = server.Createobject("ADODB.RECORDSET") '레코드셋 객체를 생성합니다.
sql = "select Title from " & tblname & " order by no asc"
rs.pagesize = pagesize 'rs.pagesize에 위에서 선언한 pagesize 갯수를 넣어 실제로 반영되게 합니다.
rs.open sql,conn, 1 '커서타입을 1로 줘서 레코드셋을 오픈합니다. 커서타입과 락타입은 여기서 오렌지님
'이 올린글을 참조하세요.
if not rs.eof then '레코드가 존재하면
rs.absolutepage = page '넘어온 page를 rs.absolutepage에 넣어서 실제로 페이지에 반영되게 합니다.
pagecount = rs.pagecount '전체 페이지 수를 pagecount에 저장합니다.
'recordcount가 87이고 rs.pagesize를 10으로 지정했으면 페이지는 9페이지가 됩니다.
'10개의 레코드로 구성된 8개의 완전한 페이지와 7개의 레코드로 구성된 1개의 페이지
response.write "전체 페이지 수:" & pagecount & "<br>" '실제로 찍어보면 이해가 빠릅니다.
i = 1
do until rs.eof or i > rs.pagesize 'record의 끝이거나 i가 pagesize보다 작을때까지 루프를 돕니다
response.write rs("title") & "<br>"
rs.movenext
i = i + 1
loop
end if
response.write "<br>" '보기좋게 하기 위해서 한칸 띄우고^^
'//-------------------------실제 페이징처리 부분입니다.---------------------------------//
blockpage=int((page-1)/pageset)*pageset+1 '블록페이지입니다. pageset의 기준을 정해줍니다.
'이것도 아래 블록페이지를 찍어주는 부분을 보시면 이해가 빠릅니다.
response.write "블럭페이지는 :" & blockpage & "<br>"
nextpage = true '이전페이지로 이동하는 링크를 나타낼 변수입니다. default값은 참입니다.
prevpage = true '다음페이지로 이동하는 링크를 나타낼 변수입니다. default값은 참입니다.
if blockpage - pageset < 0 then '블록페이지에서 페이지셋을 뺀 값이 0 보다 작으면 이전 페이지가 없는 것입니다.
prevpage = false '블록페이지는 찍어 보시면 알겠지만 1, 11, 21 이렇게 페이지셋의 처음 값을
end if '나타냅니다. 페이지셋은 위에 pageset 변수에 값을 정해주기 나름이지만
'[1][2][3][4][5][6][7][8][9][10]과 같이 페이지 이동을 위한 페이지의 값
'을 표시합니다. 블럭페이지가 1이고 페이지셋이 10일때 1 - 10을 빼면 값이 -9
'로 0보다 작습니다. 이때는 이전 페이지가 없는 것입니다.
'블럭페이지가 11이고 페이지셋이 10일때 11 - 10을 빼면 값이 1로 0보다 큽니다.
'이때는 이전페이지가 있는 것입니다.
if pagecount - blockpage < pageset then '다음페이지는 페이지카운트에서 현재의 블록페이지를 뺀값이 페이지셋보다
pageset = pagecount - blockpage + 1 '크면 다음페이지가 없는 것입니다.
nextpage = false '페이지카운트는 전체페이지의 갯수입니다.
end if
if prevpage then '이전 페이지를 클릭했을때 이동할 페이지를 정의합니다.
prevpage=blockpage-1
response.write "<a href =" & listfile & "?page="&prevpage&"><b>[이전]</b></a> "
end if
'페이지셋을 뿌려주는 부분입니다. 이해를 쉽게 하기 위해서는 for i = 1 to pagecount 까지 뿌려보는 것도 하나의 방법입니다.
for i = blockpage to blockpage + pageset - 1
if cint(page) = i then
response.write "<b><font color=red>" &i& "</font></b>"
else
response.write "<a href =" & listfile & "?page="&i&">[" & i & "]</a>"
end if
next
if nextpage then
nextpage=blockpage+pageset
response.write " <a href =" & listfile & "?page="&nextpage&"><b>[다음]</b></a>"
end if
'//--------------------------페이징 끝-----------------------------------------------//
%>
문자열중 Keyword만 Highlighting 처리합니다.
실행을 하면 Highlight function 에 인자로 넘겨주는 '하이라이트' 의 색깔을 아래와 같이 바꿉니다. Font Color도 인자로 넘길때
지정 가능합니다.
예) 하이라이트 예제입니다. replace function에 의해서 replace는 bold 처리하고 하이라이트 function에 의해서 '하이라이트'는 붉은 색으로 처리합니다.
만드신분 : Konstantin Vasserman (CodeProject)
<%
myText = "하이라이트 예제입니다. replace function에 의해서 replace는 bold 처리하고 "
myText = myText & "하이라이트 function에 의해서 '하이라이트'는 붉은 색으로 처리합니다."
myText = Replace(myText, "replace", "<b>replace</b>", 1, -1, 1)
'*****************************************************************************
' HIGHLIGHT function will search text for a specific string
' When string is found it will be surrounded by supplied strings
'
' NOTE: Unfortunately Replace() function does not preserve the original case
' of the found string. This function does.
'
' Parameters:
' strText - string to search in
' strFind - string to look for
' strBefore - string to insert before the strFind
' strAfter - string to insert after the strFind
'
' Example:
' This will make all the instances of the word "the" bold
'
' Response.Write Highlight(strSomeText, "the", "<b>", "</b>")
'
Function Highlight(strText, strFind, strBefore, strAfter)
Dim nPos
Dim nLen
Dim nLenAll
nLen = Len(strFind)
nLenAll = nLen + Len(strBefore) + Len(strAfter) + 1
Highlight = strText
If nLen > 0 And Len(Highlight) > 0 Then
nPos = InStr(1, Highlight, strFind, 1)
Do While nPos > 0
Highlight = Left(Highlight, nPos - 1) & _
strBefore & Mid(Highlight, nPos, nLen) & strAfter & _
Mid(Highlight, nPos + nLen)
nPos = InStr(nPos + nLenAll, Highlight, strFind, 1)
Loop
End If
End Function
'********************************************************************************
Response.Write Highlight(myText, "하이라이트", "<font color=red>", "</font>")
%>
|
Danny's 유용한 ASP 팁s
| ||
|
|
Danny's 유용한 ASP 팁s
| |||
|
|
Danny's 유용한 ASP 팁s
| ||
|
|
Danny's 유용한 ASP 팁s
| |||
|
저희 카페에는 없어서 퍼왔습니다. 아무래도 자료 많은게 좋을것 같아서요
|
Algorithm
| |||||
|
RGB값을 받아서 헥사값으로 변환해 주는 함수입니다.
너무 간단해서 주석은 달지 않았습니다.
<%
Function RGB2HTMLColor( RColor, GColor, BColor )
Dim HexR, HexB, HexG
Dim sTemp
'RColor
HexR = Hex(RColor)
If Len(HexR) < 2 Then
HexR = "0" & HexR
End If
'GColor
HexG = Hex(GColor)
If Len(HexG) < 2 Then
HexG = "0" & HexG
End if
'BColor
HexB = Hex(BColor)
If Len(HexB) < 2 Then
HexB = "0" & HexB
End if
RGB2HTMLColor = "#" & HexR & HexG & HexB
End Function
Response.Write RGB2HTMLColor( 255, 100, 255 )
%>
해외 사이트에서 퍼왔습니다.
문자열중 단어가 시작되는 첫문자를 대문자로 변환(Converting) 해줍니다.
<%
Function Str2ProperCase(sValue)
iPos = 1
Do While InStr(iPos, sValue, " ", 1) <> 0
iSpace = InStr(iPos, sValue, " ", 1)
sTemp = sTemp & UCase(Mid(sValue, iPos, 1))
sTemp = sTemp & LCase(Mid(sValue, iPos + 1, _
iSpace - iPos))
iPos = iSpace + 1
Loop
sTemp = sTemp & UCase(Mid(sValue, iPos, 1))
sTemp = sTemp & LCase(Mid(sValue, iPos + 1))
Str2ProperCase = sTemp
End Function
'EXAMPLE:
sValue = Str2ProperCase("THIS IS A TEST")
response.write sValue 'Displays This Is A Test
%>
txtemail 문자열에서 Instr 함수를 이용, 해당되는 문자 "@", "." 가 있나 없나, 문자열 길이가 7보다 작은가를
체크해서 유효한 이메일 인지를 검사합니다. 닷넷의 경우는 RegularExpressionValidator 컨트롤을 사용하면
이메일 정도는 정규식을 이용해서 간단하게 검사해줍니다.
<%
Function EmailChk( txtemail )
Dim strMessage
if instr( txtemail, "@" ) = 0 OR instr( txtemail, "." ) = 0 OR Len( txtemail ) < 7 Then
strMessage = "유요하지 않은 이메일입니다"
else
strMessage = "유요한 이메일입니다."
end if
EmailChk = strMessage
end Function
Response.Write EmailChk( "test@test.com")
%>
ASP에서 join과 split을 이용한 문자열 파싱(parsing)
저자: Daniel Joe | 날짜: 2001년 08월 17일
join과 split는 문자열을 파싱(parsing)함에 있어 매우 유용한 함수들이다. 같단히 설명하자면, join은 하나의 일차원 배열의 내용을 하나의 문자열로 만드는 함수이고, split은 하나의 문자열 내용을 하나의 일차원 배열로 나누어 담는 함수이다.
join에 대한 문법은 다음과 같다:
join(list[, delimiter])
여기서 list는 문자열로 연결시킬 내용들이 들어 있는 배열을 나타낸다. Delimeter는 배열에 있는 요소들로부터 문자열을 만들 때 각 요소 사이에 들어갈 문자열을 의미한다. 이 값은 옵션으로 이것을 지정하지 않으면 내부적으로 빈 문자열(" ")로 처리된다. 이제 간단한 예를 한 번 살펴 보도록 하자.
Dim OneDimArray(5)
OneDimArray(0) = "Hello,"
OneDimArray(1) = "my"
OneDimArray(2) = "name"
OneDimArray(3) = "is"
OneDimArray(4) = "Daniel!"
Dim strSentence
strSentence = join(OneDimArray)
위의 코드는 strSentence에 "Hello, my name is Daniel!"을 저장하게 된다. 만일 strSentence = join(OneDimArray) 부분을 strSentence = join(OneDimArray, ",") 부분으로 변경하면 strSentence에는 "Hello,,my,name,is,Daniel!"이 저장된다. 즉, 디리미터(delimeter, 구분자)는 앞의 경우 디폴트인 " " 이고, 후자의 경우는 ","인 것이다. 만일 배열의 각 요소를 하나의 문자열로 만들 때 각 요소 사이의 구분자가 없이 붙이고 싶을 경우는 단순히 strSentence = join(OneDimArray, "")라고 해주면 된다. 그 결과는 "Hello,mynameisDaniel!"이 될 것이다.
split은 join의 반대 결과를 만든다. split은 문자열을 취하여 문자열의 각 요소들을 적절한 기준으로 잘라 내 일차원 배열로 담아낸다. split의 문법은 다음과 같다:
split(String Expression[, delimiter[, count[, compare]]])
여기서 반드시 필요한 파라미터는 배열로 담을 문자열, Expression이다. Delimeter는 join과 마찬가지로 옵션이다. 디폴트는 " " 이다. count는 결과로 반환할 부분 문자열의 갯수이다. compare는 부분 문자열을 비교하는 방법을 결정한다. 이제 간단한 예를 한 번 살펴 보도록 하자.
Dim strSentence
strSentence = "Hello, my name is Daniel!"
Dim OneDimArray
OneDimArray = split(strSentence)
위의 코드는 strSentence에 담겨 있는 문자열을 OneDimArray란 일차원 배열의 각 요소에 "Hello,", "my", "name", "is", "Daniel!"을 저장한다. 만일 OneDimArray 배열에 3 요소만 저장하고 싶은 경우 count 파라미터를 이용하여 부분 문자열의 갯수를 정해주면 된다. 즉, OneDimArray = split(strSentence) 부분을 OneDimArray = split(strSentence, " ", 3)으로 변경시켜주면 된다. 이 결과는 "Hello,", "my", "name is Daniel!"이 된다. 만일 구분자로 컴마(,)를 사용하고 싶다면 OneDimArray = split(strSentence) 부분을 OneDimArray = split(strSentence, ",")로 변경시켜주면 된다. 이 결과는 "Hello", "my name is Daniel!"이 될 것이다.
앞에서도 언급했지만 join과 split은 서로 반대 관계이다. 예를 들어, 다음과 같은 코드를 보자.
Dim strSentence, strCopy
strSentence = "Hello, my name is Bob!"
strCopy = join(split(strSentence))
위의 코드에서 strCopy와 strSentence는 동일한 값을 갖는다.
지금까지 join과 split의 사용 방법에 대해 알아 보았다. 그렇다면 이 함수들은 언제 유용하게 사용될 수 있을까? 사실 ASP에서 문자열을 조작함에 있어 join과 split의 사용은 필수적이다. 하나의 예를 들기 위해 지난 시간에 살펴보았던 "AdRotator를 이용하여 배너 광고 로테이션 시키는 방법"에서 사용한 AdRotator.txt 파일을 살펴 보도록 하자. 그 파일에는 다음과 같은 형식의 데이터들이 저장되어 있다:
Advertiser Name
Advertiser URL
Advertiser Category
Banner ID
Comment
*
Advertiser Name
Advertiser URL
Advertiser Category
Banner ID
Comment
*
Advertiser Name
Advertiser URL
Advertiser Category
Banner ID
Comment
*
...
이런 텍스트 파일을 이용하여 작업을 할 때 제일 먼저 하는 일은 FileSystemObject 객체를 이용하여 전체 텍스트 내용을 하나의 문자열로 읽어 들이는 것이다. 그 문자열을 str이란 변수로 담았다고 한다면 다음으로 할 일은 recArray = split(str, "*")을 해주는 것이다.
이렇게 함으로써 하나의 레코드 단위를 배열의 각 요소로 저장할 수가 있다. 마지막으로 레코드에 있는 각각의 요소를 얻으려면 elementArray = split(recArray(i), chr(13))이라고 해주면 된다. 여기서 chr(13)은 라인이 분리되어 있는 값을 의미한다.
이런 과정을 거침으로써 텍스트 파일의 내용을 적절히 파싱(parsing)을 할 수 있게 된다.
ASP로 개발작업을 할때 db연결 부분이나 공통으로 필요한 부분은 따로 파일로 작성해서
필요시 포함해서 쓰는 경우가 많습니다.
첫번째는 #include 를 이용한 방법이고 두번째는 Server.Execute를 이용한 방법입니다.
근데 이 두가지 방법이 외부파일을 포함해서 쓰는 공통의 방법이면서 몇가지 차이점이 있습니다.
차이점
1) #include는 IIS에서 ASP 파일을 실행하기 이전에 먼저 처리하지만 Server.Execute는 ASP 파일 실행시 같이 처리하게 됩니다.
두문장이 삽입되는 생김새만 봐도 눈치챌수 있습니다.
2) #include는 삽입되는 파일과 삽입하는 파일의 변수가 공유가 되지만 Server.Execute는 변수 공유가 되지 않습니다.
이부분은 아래 예제를 보면 이해가 가실겁니다.
예제1) Test.ASP파일의 내용이 다음과 같다고 할때
<% moneyValue = 100%>
#include로 test.asp를 포함시킨 moneyValue의 값은 100이 출력됩니다.
<%
moneyValue = "10000"
%>
<!--#include file="test.asp"-->
<%
Response.Write moneyValue
%>
Server.Execute로 test.asp를 포함시킨 moneyValue의 값은 Test.asp파일의 내용을 무시하고 그냥 100이 출력됩니다.
<%
moneyValue = "10000"
Server.Execute("Test.asp")
Response.Write moneyValue
%>
그래도 Server.Execute문을 써야할때가 있습니다. 파일을 동적으로 삽입시켜야 할때입니다.
위에서 보셨듯이 #include는 asp구문이 끝난다음 삽입됩니다. html의 주석처리 이후에 #include문을
쓰기 때문에 <!--#include file=<%Thema%>--> 이런식으로 쓸수가 없습니다.
하지만 Server.Execute는 특정변수에다 조건에 따라서 삽입되는 파일경로를 달리하여
다음과 같이 쓸수 있습니다.
<%
if chkThema = 1 then
Thema = "event.asp"
else
Thema = "nomal.asp"
end fif
Server.Execute(Thema)
%>
= FormatDateTime 함수 =
FormatDateTime(Date[,NamedFormat])
Date : 필수적인 인수. 날짜식을 지정합니다
NamedFormat : 선택적인 인수로써 날짜/시간 형식을 나타내는 숫자 값입니다.
이 인수를 생략하면 vbGeneralDate를 사용합니다.
|
- 예제 -
<%
Response.Write FormatDateTime(Now, 0) & "<BR>"
Response.Write FormatDateTime(Now, 1) & "<BR>"
Response.Write FormatDateTime(Now, 2) & "<BR>"
Response.Write FormatDateTime(Now, 3) & "<BR>"
Response.Write FormatDateTime(Now, 4) & "<BR>"
%>
<!-- Formatnumber, Formatcurrency 함수를 이용한 천단위 콤마찍기 짧막한 예제입니다.
혹시 모르시는 분들 있을까봐 올립니다. -->
<%
Dim moneyValue
moneyValue = "100000"
If IsNumeric(moneyValue) then 'moneyValue의 값이 숫자인지 아닌지 IsNumeric 함수를 이용해서 체크합니다
response.write(formatnumber( moneyValue, 0 )) '0은 소숫점 자리수의 의미, Default가 2라서 소수점 자리를
response.Write "<br><br>" '나타내고 싶지 않으면 0을 써주세요
end if
If IsNumeric(moneyValue) then
response.Write(formatcurrency( moneyValue, 0 )) '0은 소숫점 자리수의 의미, Default가 0이라서 생략가능
end if
%>
<!-- Split 함수를 이용해서 문자열에서 특정문자를 제거하는 함수입니다.
혹시 필요하신분 있을까봐 간단히 만들어 봤습니다. -->
<%
Function Get_AbString( strSource, chrSource )
Dim strTemp, chrTemp, strDest
strTemp = strSource
chrTemp = chrSource
'Split 함수: 지정된 수의 부분 문자열을 포함하는 0부터 시작하는 1차원 배열을 반환합니다.
'strDest에는 chrSource의 갯수를 반환합니다. 여기서는 2
'분리된 문자열은 strDest(0) 부터 시작해서 반환한 strDest의 갯수만큼의 1차원 배열에 저장됩니다.
'여기서는 strDest(0), strDest(1), strDest(2)
strDest = Split( strTemp, chrTemp )
strTemp = ""
for i = 0 to ubound(strDest)
strTemp = strTemp & strDest(i)
next
Get_AbString = strTemp
End Function
Response.Write Get_AbString( "2,000,000", "," )
%>
★ 커서타입
|
★ 락타입
|
<%
'//Addnew 함수는 레코드셋을 이용해 데이타를 추가하는 방식이다.
'//Addnew 함수를 통해서 데이타를 추가하면 마지막에 반드시 Update라는 메소드가 있어야지 적용이된다
'//기존 쿼리를 사용하는 방법이 레코드셋을 이용하는것 보다 속도는 조금빠르지만 초보자에게는 약간
'//복잡한면이 없지 않다...
'//기존 쿼리방식은 많은 insert 문중 에러가 발생하면 Dbcon.Execute SQL 을 가리키지만 이방법은
'//어디가 잘못되었는지 바로 지적해준다 디버깅면에서 추천할만하다
'//하지만 이방법은 모든 OLEDB 제공자가 이기능을 지원하지 않는다는 것이다
Dim strConnect
Dim Rs
strConnect = "Provider=SQLOLEDB.1;Data Source=xxxx;Initial Catalog=xxxx;user ID=xxxx;password=xxxx;"
Set Rs = server.CreateObject("ADODB.Recordset")
With Rs
.open "테이블명",strConnect, adOpenStatic, adLockPessimistic, adCmdTable
.Addnew
.Fields("uid") = "abcd"
.Fields("name") = "홍길동"
.Fields("memo") = "abcdefg hijk lmn"
.Fields("idate") = now()
.Update
.Close
End With
set Rs=nothing
response.write "새로운 데이타가 추가되었습니다."
%>
ASP페이지에 Excel 스프레드시트를 표시하는 간단한 예제입니다.
쿼리문에 있는 [TEST$] 는 Excel 시트명이며 자주 에러를 발생시키는 부분과 GetString 함수는 주석으로 설명하였습니다
------------------------------------예제는 여기서부터 -------------------------------------------------------------------
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML>
<HEAD>
<TITLE> ASP 페이지에 Excel 스프레드시트 표시하기 </TITLE>
</HEAD>
<BODY>
<%
Set dbCon = Server.CreateObject("ADODB.Connection")
strConnect = "Driver={Microsoft Excel Driver (*.xls)};DBQ=" & Server.MapPath("\") & "\TEST.xls;" '엑셀파일 경로
'다음과 같은 오류가 나왔다면 엑셀파일이 열려있거나, 아니면 사용자권한이 파일접근 금지되어 있을경우입니다
'Microsoft OLE DB Provider for ODBC Drivers 오류 '80004005'
'[Microsoft][ODBC Excel Driver]일반 오류 레지스트리 키 'Temporary (volatile) Jet DSN for process 0x8c0 Thread 0xa9c DBC '0x16d6764 Excel'을(를) 열 수 없습니다.
dbCon.Open strConnect
SQL = "Select * from [TEST$]"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open SQL, dbCon
'ADO 2.0 이상에는 GetString이라는 함수가 있습니다. 이 함수를 이용하면 Do..Loop부분과 레코드셋의 eof를 체크하는 부분이 필요없습니다
exlValue = rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<TABLE border=1>
<TR><TD>
<% Response.Write(exlValue)%>
</TD></TR>
</TABLE>
</BODY>
</HTML>
2탄 이어서
저번에 올린 Excel에 스프레드시트 표시하기의 발전형 예제입니다.
엑셀파일명만 알고 스프레드시트에는 무슨이름이 들어있는지 모를때 OpenSchema 메서드를 이용하여
스프레드시트명을 알아내어 스프레드시트 내용을 뿌려줍니다.
-------------------------------------예제는 여기서부터 -----------------------------------------------------------------
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML>
<HEAD>
<TITLE> ASP 페이지에 Excel 스프레드시트 표시하기 </TITLE>
</HEAD>
<BODY>
<%
Dim SheetName, dbCon, strConnect, rsList, rs
Set dbCon = Server.CreateObject("ADODB.Connection")
strConnect = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("\") & "\TEST.xls " & "; Extended Properties=Excel 8.0;" '엑셀파일 경로
dbCon.Open strConnect
'OpenSchema 메서드를 사용하여 데이터베이스의 테이블에 대한 정보가 들어있는 Recordset 개체를 반환합니다.
'스키마 상수는 다음과 같습니다.
'adSchemaColumns = 4, adSchemaProviderTypes = 22, adSchemaTables = 20
set rsList = dbCon.OpenSchema(20)
Do Until rsList.EOF Or rsList.BOF
SheetName = rsList(2) '2는 카탈로그의 Character Set을 되돌려 줍니다.
rsList.MoveNext
Loop
SQL = "Select * from [" & SheetName & "]"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open SQL, dbCon
exlValue = rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<TABLE border=1>
<TR><TD>
<% Response.Write(exlValue)%>
</TD></TR>
</TABLE>
<%
rs.Close
Set rs = Nothing
rsList.Close
set rsList = Nothing
dbCon.close
set dbCon = Nothing
%>
</BODY>
</HTML>
<%
'//GetRows 메소드는 Recordset 개체에서 데이타를 배열로 가져오는 역활을 한다.
strConnect="DSN=test;UID=sa;PWD=;"
set dbcon = server.CreateObject("ADODB.Connection")
dbcon.open strConnect
SQL = "select 필드명1, 필드명2 from 테이블명"
set rs = dbcon.Execute(SQL)
With Rs
fields = Array("memuid","name") '// 2차원 배열로 값을 저장한다.
data = .GetRows( , ,fields)
'//GetRows([Rows],[Start],[Fields])
'//인자는 생략가능하다
'//첫번째 인자는 가져올 레코드수를 지정한다 생략하면 전부다 가져온다.
'//두번째 인자는 어느레코드에서 가져올지를 정한다.
'//세번째 인자는 배열에 들어간 Field 값을 가져온다.
.close
end With
set rs = nothing
dbcon.close
set dbcon = nothing
Rcount = ubound(data,2)
'//UBound([배열명]] 배열의 요소 갯수를 알려주는 함수
%>
<table width = "100%" border="1">
<% for i=0 to Rcount%>
<tr>
<td><%=Rcount-i+1%></td>
<td><%=data(0,i)%></td>
<td><%=data(1,i)%></td>
</tr>
<%next%>
</table>
혹시나 모르시는 분 있을까봐 간단하게 예제 작성해봤습니다.
On Error Resume Next 구문은 에러가 발생해도 에러부분을 무시하고 넘기라는 명령문이며
에러발생시의 처리 루틴이 빠져있다면 화면에 아무런 에러메시지도 출력안하게 됩니다. 그럼 일단 개발자는
아래와 같은 소스에서는 DB연결 에러를 파악할수가 없게 됩니다. 쓰시게 될때는 에러처리 부분과 꼭 함께
쓰시거나 아니면 안 쓰시는게 좋습니다. 주석은 비교적 짧게 달았으나 한번 실행해 보시면 금방 감 오실겁니다
--------------------------------------- 예제는 여기서부터 -------------------------------------------------------------
<%
'On Error Resume Next 구문은 에러가 발생해도 일단 에러부분을 무시하고 넘기게 됩니다.
On Error Resume next
Dim strConnect, dbCon, rs
strConnect="DSN=test;uid=sa;pwd=1234;"
SET dbCon=server.CreateObject("ADODB.Connection")
dbCon.Open strConnect
SET rs = dbCon.execute("select uid, name, addr from TestTable where uid ='"& uid &"'")
'Error 발생했을때 처리하게 되는 루틴입니다.
if Err.Number <> 0 then
response.Write "<h2>DB연결에 실패하였습니다.</h2>"
Err.Clear
response.end
else
rs.Close
Set rs = nothing
dbCon.Close
Set dbCon = nothing
response.Write "<h2>DB연결에 성공하였습니다.</h2>"
end if
%>
쿠키 유형에는 메모리 쿠키와 디스크기반 쿠키가 있습니다. 디스크기반 쿠키는 우리가
일반적으로 생각하는 클라이언트의 디스크에 저장되는 쿠키이며 메모리 기반 쿠키는
브라우져가 종료될때까지만 유효한 쿠키입니다.
아래 예제는 메모리기반 쿠키입니다. 디스크기반 쿠키로 사용하실려면 Expires 속성을 이용하여
다음과 같이 명시해야 합니다.
Response.Cookies("TestCookie").expires = #12/31/2010 00:00:00#
아래 예제에서는 expires 부분을 ' <-- 주석으로 막아놨습니다.
쿠키의 또 한가지 알아야 할 특성은 로드밸런싱(load balancing)을 이용하거나 이용하신분들은 아시겠지만
도메인에 종속적이라는 것입니다. 도메인명이 다르면 다른 도메인으로 디스크기반 쿠키를 사용할수가 없습
니다. 그래서 도메인명이 다른 두개의 사이트의 회원로그인 정보를 공유하자는 논의는 양사 개발담당자
의 머리를 썩게 만드는 주요한 요인이 됩니다
※ 두대이상의 웹서버를 이용한 로드밸런싱에서는 별도의 세션서버를 두지 않는이상 세션정보를 쿠키에
저장하여 처리하는 것이 일반적입니다. 기회가 된다면 로드밸런싱 하에서 로그인처리와 파일업로드 부분
에 대해서 언급할 계획입니다.
-------------------------------------예제는 여기서부터 ------------------------------------------------------------
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML>
<HEAD>
<TITLE>쿠키예제</TITLE>
</HEAD>
<BODY>
<%
'Response.Cookies("TestCookie").expires = #12/31/2010 00:00:00#
'Response.Cookies를 사용하면 쿠키에 정보를 추가합니다.
Response.Cookies ("TestCookie")="쿠키예제"
'Request.Cookies를 사용하여 쿠키의 정보를 읽어들입니다.
Response.Write Request.Cookies("TestCookie")
Response.Write "<br><br>"
'쿠키에 키를 사용하면 하나의 쿠키에 여러 정보를 저장할수 있습니다.
Response.Cookies ("TestCookie")("Key1")="쿠키"
Response.Cookies ("TestCookie")("Key2")="예제"
Response.Cookies ("TestCookie")("Key3")="입니다"
'키가 사용된 쿠키의 값을 참조하기 위해서 키값을 사용합니다.
Response.Write Request.Cookies("TestCookie")("Key1")
Response.Write Request.Cookies("TestCookie")("Key2")
Response.Write Request.Cookies("TestCookie")("Key3")
%>
</BODY>
</HTML>
여기 없는 것 같아서 퍼왔읍니다.
아래글은 트랙백의 기본개념보다는 windows + asp 환경에서의 기술적 구현을 위해 간단하게 작성된 소스입니다. 따라서 트랙백의 기본개념을 이해하신후 소스를 보시는것이 도움이 되실것입니다.또한 보다 확장적인 서비스를 위해서는 아래 소스외에 더 많은 부분을 추가하셔야 합니다.
1. 트랙백 핑 받기
<%
'변수 처리
bidx = Request("bidx")
strTitle = Request("title")
strExcerpt = Request("excerpt")
strURL = Request("url")
'콘텐츠 타입
Response.ContentType = "text/xml"
'변수 확인
If strURL="" or strTitle = "" or bidx = "" Then
Response.Write "<?xml version=""1.0"" encoding=""iso-8859-1""?>"
Response.Write "<response>"
Response.Write "<error>1</error>"
Response.Write "<message>Not Enough Arguments.</message>"
Response.Write "</response>"
Response.End
End If
'내 블로그에 글이 있는지 확인
If 해당글의수 = 0 Then
Response.Write "<?xml version=""1.0"" encoding=""iso-8859-1""?>"
Response.Write "<response>"
Response.Write "<error>1</error>"
Response.Write "<message>Not Exist Post.</message>"
Response.Write "</response>"
Response.End
End If
set rs = Server.CreateObject("ADODB.Recordset")
with rs
.Open trackback_table,접근문자열,adOpenStatic,adLockPessimistic,adCmdTable
.addnew
.fields ("글번호 필드명") = opt_insert_text (bidx)
.fields ("주소 필드명") = opt_insert_text (strURL)
.fields ("제목 필드명") = opt_insert_text (strTitle)
.fields ("내용 필드명") = opt_insert_text (strExcerpt)
.fields ("날짜") = now
.update
.close
end with
set rs = nothing
'정상적으로 완료되었으면 성공했다는 대답을 보내자.
Response.Write "<?xml version=""1.0"" encoding=""iso-8859-1""?>"
Response.Write "<response>"
Response.Write "<error>0</error>"
Response.Write "<message>TrackBack Success.</message>"
Response.Write "</response>"
%>
첫번째로 트랙백은 규정적으로 4개의 변수값을 전송합니다. 글제목(title),글주소(url),글내용(exerpt),블로그명(blog_name) 입니다. 여기서 필수요소는 url 입니다. 위 소스에서는 블로그명을 포함시키지 않았습니다. 그리고 글번호는 해당 글의 존재유무를 확인하기 위해 트랙백 주소에서 GET 형태로 받아옵니다.
두번째로 인코딩되는 xml 중 <error> 부분이 가장 중요합니다. 즉, error 값으로 트랙백 핑을 보낸쪽에다 대답을 하는 것입니다.0이면 성공이고 1이면 실패입니다. 그리고 <message>부분은 말그대로 추가설명입니다. 그리고 트랙백 핑은 POST 형태로 값을 받습니다. 받아오는 변수들을 Request.Form 형태로 정의해주는것이 더 좋을듯 하네요.
세번째로 위 소스에서는 간단한 xml 이라 굳이 Msxml2.DOMDocument 같은 xml 관련 서버 컴포넌트를 사용하지 않았습니다.
2. 트랙백 핑 보내기
<%
b_tb = "핑을 보낼 블로그 게시물의 트랙백 주소"
if b_tb <> "" then '만약 트랙백 주소가 입력되었다면 ..
' 여기서 부터 트랙백 처리
' 핑을 보낼 준비하자
x_Posturl = Server.URLEncode(나의 글의 고유주소)
x_BlogName = Server.URLEncode(나의 블로그명)
x_Title = Server.URLEncode(나의 글의 제목)
x_Excerpt = Server.URLEncode(나의 글의 내용)
Str_tb="title="&x_Title&"&url="&x_Posturl&"&excerpt="&x_Excerpt&"&blog_name="&x_BlogName
' 트랙백 핑을 보내자
set xml = server.CreateObject("msxml2.xmlhttp")
xml.open "POST", "" & b_tb & "", false
' 몇가지 헤더처리
xml.setRequestHeader "Accept-Language","ko"
xml.setRequestHeader "Accept-Encoding","gzip, deflate"
xml.setRequestHeader "Content-Type","application/x-www-form-urlencoded"
xml.setRequestHeader "Connection","Keep-Alive"
xml.setRequestHeader "Cache-Control","no-cache"
xml.send (Str_tb)
' 트랙백 핑 성공여부
If InStr(1, xml.responseText, "<error>0</error>") Then
' 성공일경우 처리
Else
' 실패일경우 처리
End If
Set xml = Nothing
end if
%>
일반적으로 글의 저장 또는 편집시 사용하실수 있습니다. 그리고 Str_tb 변수 정의 하면서 POST 로 넘기는 변수명은 변경하시면 안됩니다. 또한 위 소스에서는 msxml2.xmlhttp 컴포넌트를 이용하여 POST 형태로 핑을 전송합니다. 트랙백 핑의 성공여부는 받아온 xml 을 디코딩 하셔도 되지만 그냥 <error>부분만 체크하기 위해 instr 로 처리하였습니다. 추가적으로 <message> 부분도 체크하여 성공 또는 실패시의 메시지를 받아오실수도 있습니다. 간혹 핑 전송시 한글이 깨어진다는 질문이 있는데, 이 경우 UrlEncoding 을 시키지 않으셨을때가 가장많습니다. 그외에는 위와 같은 방법으로 무난하게 성공하실것 입니다.
출처: http://nbloger.com/blog/xbb.asp?blogid=iendev&action=view&b_idx=205
사이트에서 월별, 주별 이벤트 참여자의 순위를 랭크하는 작업이 있어서 기존에 유통되는 자바스크립트 함수를
asp버전으로 급히 변환(converting)한 것입니다. 함수는 총3개로 구성되어 있으며 하단의 weekCount 함수
에 년,월의 인자만 넘겨주면 이번달에 속한주가 몇주까지 있나를 리턴(return) 해 줍니다.
처음에 올린 datepart 함수를 이용하면 해당월에 속한 주수를 구할수 있을것 같으나 쉽지는 않습니다. 처음 예제 그대로
따라하시면 해당월에 속한주가 6주까지도 있다는 괴상한 값을 받을 것입니다.
-> wcountMonth = datepart("ww", today) - datepart("ww", firstdate) + 1 이부분에 dateserial 함수를 이용했을경우 5~6주가 넘어옴
------------------------------------------------함수는 여기부터 ---------------------------------------------------------
<%
function isLeapYear (Year)
dim bisReturn
if (( Year mod 4 = 0 ) and (( Year mod 100 ) <> 0 ) or (( Year mod 400 ) = 0 )) then
bisReturn = true
else
bisReturn = false
end if
isLeapYear = bisReturn
end function
function getDayInMonth(month,year)
dim days
if( month = 1 or month = 3 or month = 5 or month = 7 or month = 8 or month = 10 or month = 12 ) then
days = 31
else
if ( month = 4 or month = 6 or month = 9 or month = 11 ) then
days = 30
else
if IsLeapYear(Year) then
days = 29
else
days = 28
end if
end if
end if
getDayInMonth = days
end function
function weekCount(thisYear, thisMonth)
dim i, j
i = 0
j = 0
for i = 1 to getDayInMonth(cint(thisMonth), cint(thisYear))
tempDay = thisYear & "-" & thisMonth & "-" & cstr(i)
'월요일이 나올때 마다 j값을 증가시킨다 참고: 1은 일요일, 2는 월요일, 3은 화요일, 4는 수요일,
'5는 목요일, 6은 금요일, 7은 일요일
if weekday(tempDay) = 2 then
j = j+1
end if
next
if(( thisMonth = 1 ) or ( thisMonth = 10 )) then
j = 5
end if
weekCount = j
end function
%>
<% '//---- 해당년과 해당월을 weekCount 함수에 넘기면 해당월에 몇주가 있나를 리턴해줍니다. ----//
<% response.Write weekCount( "2006", "9" ) %>
----------------------------------------------- 함수 끝 -------------------------------------------------------------
기회가 되면 컨버팅전의 자바스크립트 함수도 올리도록 하겠습니다.
이번달의 시작일과 마지막일을 구하는 간단한 예제입니다.
DateSerial 함수의 ToYear 와 ToMonth 의 인자는 "2006" "11" 과 같은 형식으로 넘겨주시면 됩니다.
ex) DateSerail( "2006", "11", 1 )
<%
ToYear = Year(Date)
ToMonth = Month(Date)
FirstDay = DateSerial(ToYear, ToMonth, 1 )
LastDay = DateSerial(ToYear, ToMonth + 1 , 0 )
Response.Write " 이번달의 시작일은 " & FirstDay & " 이고 마지막일은 " & LastDay & " 입니다 "
%>
페이지 처리시 캐쉬에 파일을 남기지 말아야 할경우 asp페이지 맨상단에
아래의 세줄을(주석빼고) 추가하세요
※캐쉬를 사용하지 않음으로 서버에 상당한 무리를 줄수도 있습니다.
꼭 필요할때만 사용하세요.
<% '브라우저와 서버가 캐쉬를 사용하지 말것을 지정 %>
<% Response.CacheControl = "no-cache" %>
<% Response.AddHeader "Pragma", "no-cache" %>
<% '캐쉬돈 페이지가 만료될때까지의 기간, -1은 즉시만료 입니다. %>
<% Response.Expires = -1 %>
혹시 모르실 분을 위한 팁!!!
걍 퍼가시면 연결 안되고, dbconnect= 이하 부분을 자신의 database설정과 맡게 변경해주셔야 됩니다.
변경 부분은 주석으로 달아 놓았으니 참고하세요
<%
dim Tblname
Tblname = request("Tblname")
uid = request("uid")
name = request("name")
addr = request("addr")
'ODBC설정없이 db연결하기 시작
'xxx,xxx,xxx,xxx <---- 이부분에 database서버의 ip를 기록합니다.
'database <---- 이부분에 생성된 database명을 기록합니다.
'userid <------ 이부분에 데이타베이스 사용자명을 기록합니다.
'pwd <------ 이부분에 데이타베이스 사용자의 password를 기록합니다.
dim dbConnect, db
dbConnect = "Provider=SQLOLEDB;Data Source=xxx,xxx,xxx,xxx;Initial Catalog=database;user ID=userid;password=pwd;"
set db = server.createObject("ADODB.Connection")
db.open dbConnect
'db 오픈끝
'db가 오픈되었으면 해당작업을 합니다. 여기서는 간단한 insert 작업^^
dim Sql
Sql = "insert into "& Tblname &"(uid, name, addr, idate) "
Sql = sql & "values('"&uid&"','"&name&"','"&addr&"',getdate())"
db.execute Sql
'db를 닫고 초기화합니다.
db.close()
set db = nothing
%>
퍼왔습니다. 출처가 기억안나네요.
<HTML>
<BODY>
<center><h2>ServerVariable All</h2></center>
<TABLE border="1">
<TR><TD><center>Key</center></TD>
<TD><center>Value</center></TD></TR>
<% For Each key in Request.ServerVariables %>
<TR>
<TD><center><font face="돋움" size="2"><% = key%></font></center></TD>
<TD><font face="돋움" size="2">
<%
if Request.ServerVariables(key) = "" Then
Response.Write " "
else
Response.Write Request.ServerVariables(key)
end if
%>
</font></TD></TR>
<% Next %>
</TABLE>
</BODY>
</HTML>
강좌 최초 작성일 : 2003년 07월 25일
강좌 최초 작성일 : 2000년 12월 28일